home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1996 April: Mac OS SDK / Dev.CD Apr 96 SDK / Dev.CD Apr 96 SDK2.toast / Development Kits (Disc 2) / ScriptX / Draggable ScriptX Folders / utils / widgets / listbox.sx < prev    next >
Encoding:
Text File  |  1995-12-06  |  13.3 KB  |  550 lines  |  [TEXT/ttxt]
  1. class ListSelection (TwoDShape)
  2. class variables
  3.     fill:(new Brush color:BlackColor)
  4. instance vars
  5.     _descent
  6. class methods
  7.     method afterInit self #rest args -> (
  8.         apply nextMethod self args
  9.         ListSelection.fill.inkMode := @srcXor
  10.     )
  11. end
  12.  
  13. ------------------------
  14.  
  15. method init self { class ListSelection } #rest args #key \
  16.     width:(10) ->
  17. ( 
  18.     local height := 10
  19.     local bounds := new Rect x2:width y2:height
  20.     apply NextMethod self boundary:bounds fill:ListSelection.fill args
  21. )
  22.  
  23. method afterInit self {class ListSelection } #rest args #key \
  24.     font:(theSystemFont) \
  25.     parent:         ->
  26. (
  27.     apply NextMethod self args
  28.     changeFont self font 1
  29.     if (not (isAKindOf parent TwoDPresenter)) do
  30.         report BadParameter "parent must be a TwoDPresenter!"
  31.     ThreadCriticalUp()
  32.     local subs := parent.subPresenters
  33.     if (subs = undefined) then
  34.         parent.subPresenters := #(self)
  35.     else
  36.         prepend subs self
  37.     self.presentedBy := parent
  38.     ThreadCriticalDown()
  39. )
  40.  
  41. method changeFont self {class ListSelection} font theLine ->
  42. (
  43.     self.height := font.leading
  44.     self._descent := font.descent - 2 -- frame offset
  45.     selectLine self theLine @dontAction
  46. )
  47.  
  48. method selectLine self {class ListSelection} the_line doAction ->
  49. (
  50.     self.y := self.height * (the_line - 1) + self._descent
  51. )
  52.  
  53. -----------------
  54.  
  55. class ListBox (TextPresenter)
  56. instance vars
  57.     numLines:0                -- number of lines in the list of text
  58.     _font
  59. end
  60.  
  61. method init self { class ListBox }  #rest args #key \
  62.     font:(theSystemFont)    \
  63.     width:(300)                \
  64.     list:(#())                ->
  65. ( 
  66.     apply nextMethod self target:"" boundary:(new Rect x2:width y2:0) args 
  67.     SetDefaultAttr self @alignment @tty
  68.     self.font := font
  69.     self.inset.x := 5
  70.     self.list := list
  71. )
  72.  
  73. method fontGetter self {class ListBox} -> self._font
  74. method fontSetter self {class ListBox} newFont ->
  75. (
  76.     self._font := newFont
  77.     setDefaultAttr self @font newFont.font
  78.     setDefaultAttr self @leading newFont.leading
  79.     setDefaultAttr self @firstLineLeading (newFont.leading - newFont.descent + 2)
  80.     setDefaultAttr self @size newFont.fontSize
  81.     recalcHeight self
  82.     newFont
  83. )
  84.  
  85. method listSetter self {class ListBox} new_list -> 
  86. (
  87.     -- clear out targets
  88.     self.target := "" as String
  89.     
  90.     -- re-build lists
  91.     forEach new_list (item arg -> \
  92.             addMany self.target ((item as String) + "\r")) self
  93.             
  94.     -- select the first line of each column
  95.     self.numLines := new_list.size
  96.     recalcHeight self
  97.     new_list
  98. )
  99.  
  100. method listGetter self {class ListBox} ->
  101. (
  102.     local listText := self.target
  103.     local maxSize := size listText
  104.     local args := #(listText,1,0,maxSize)
  105.     local returnList := #()
  106.     repeat while (FindNthContext args @paragraph) do (
  107.         append returnList (CopyFromTo(listText,args[3],args[4] - 1))
  108.         args[3] := args[4]
  109.         args[4] := maxSize
  110.     )
  111.     returnList
  112. )
  113.  
  114. method getListOrdinal self {class ListBox} item ->
  115. (
  116.     local listText := self.target
  117.     local maxSize := size listText
  118.     local args := #(listText,1,0,maxSize)
  119.     local ord := 1
  120.     repeat while (FindNthContext args @paragraph) do (
  121.         if (item = (CopyFromTo(listText,args[3],args[4] - 1))) do
  122.             return ord
  123.         ord := ord + 1
  124.         args[3] := args[4]
  125.         args[4] := maxSize
  126.     )
  127.     return 0
  128. )
  129.  
  130.  
  131. method recalcHeight self {class ListBox} ->
  132. (
  133.     self.height := self.numLines*self.font.leading + self.font.descent
  134. )
  135.  
  136. global upReceiver
  137. global downReceiver
  138.  
  139. class ScrollBox(ScrollingPresenter)
  140. class variables
  141.     mouse:(new MouseDevice)
  142. instance variables
  143.     doubleClickTime:(getDblClickTime())
  144.     doubleClickAction:(undefined)
  145.     lastTime:0
  146.     lastLine:0
  147.     authordata:(undefined)
  148.     
  149.     downInterest
  150.     upInterest
  151.  
  152.     _selectedLine:0
  153.     selectAction:(undefined)
  154.     selection
  155.  
  156.     maxScroll:0
  157.     stepAmount:0
  158.     pageAmount:0
  159.     scrollDirection
  160.     frame:(new Frame)
  161.     tempPoint:(new Point)
  162.     _list
  163. end
  164.  
  165. method init self {class ScrollBox} #rest args #key \
  166.     font:(theSystemFont) ->
  167. (
  168.     self.stepAmount := font.leading
  169.     apply NextMethod self args
  170.     local targetP := self.targetPresenter
  171.     self.selection := new ListSelection font:font\
  172.         width:self.width parent:targetP
  173.  
  174.     local downInterest := new MouseDownEvent
  175.     self.downInterest := downInterest
  176.     downInterest.eventReceiver := downReceiver
  177.     local upInterest := new MouseUpEvent
  178.     self.upInterest := upInterest
  179.     upInterest.eventReceiver := upReceiver
  180.     downInterest.buttons := upInterest.buttons := @mouseButton1
  181.     downInterest.authordata := upInterest.authordata := self
  182.     downInterest.presenter := upInterest.presenter := self
  183.     downInterest.priority := upInterest.priority := 6
  184.     upInterest.matchedInterest := downInterest
  185. )
  186.  
  187. method afterInit self {class ScrollBox} #rest args #key \
  188.     hasScrollBar:(false) \
  189.     value: ->
  190. (
  191.     apply NextMethod self args
  192.  
  193.     local cp := self.clippingPresenter
  194.     InsetRect cp.boundary 2 2 @mutate
  195.     cp.stationary := true
  196.     cp.fill := WhiteBrush
  197.     self.stationary := true
  198.     if (hasScrollBar) do (
  199.         local vScroll := new SimpleScrollBar orientation:@vertical
  200.         vScroll.directDrag := true
  201.         vScroll.stepAmount := self.stepAmount
  202.         self.vertScrollBar := vScroll
  203.     )
  204.     self.horizScrollBarDisplayed := @none
  205.     if (value != unsupplied) do
  206.         self.value := value
  207.         
  208. )
  209.  
  210. method set presentedBy self {class ScrollBox} val ->
  211. (
  212.     nextMethod self val
  213.     if (val == undefined) then (
  214.         removeEventInterest self.upInterest
  215.         removeEventInterest self.downInterest
  216.         )
  217.     else (
  218.         addEventInterest self.downInterest
  219.         addEventInterest self.upInterest
  220.         )
  221.     val
  222. )
  223.  
  224. method recalcRegion self {class ScrollBox} ->
  225. (
  226.     NextMethod self
  227.     SetBoundary self.frame self.boundary
  228. )
  229.  
  230. method downReceiver self {class ScrollBox} theInterest theEvent ->
  231. (
  232.     local new_selected_line
  233.     self.needsTickle := true
  234.     local tempPoint := self.tempPoint
  235.     setTo tempPoint theEvent.surfaceCoords
  236.     SurfaceToLocal self.targetPresenter tempPoint @mutate
  237.     new_selected_line := ((tempPoint.y / self.stepAmount)  as ImmediateInteger) + 1
  238.     selectLine self new_selected_line @dontAction
  239.     @accept
  240. )
  241.  
  242. method upReceiver self {class ScrollBox} theInterest theEvent ->
  243. (
  244.     local selectedLine := self._selectedLine
  245.     self.needsTickle := false
  246.     
  247.     if (selectedLine = self.lastLine) then (
  248.         local doubleClickAction := self.doubleClickAction
  249.         if (((theEvent.timeStamp - self.lastTime) < self.doubleClickTime) and
  250.             doubleClickAction != undefined) then (
  251.             doubleClickAction self.authorData selectedLine
  252.             self.lastTime := 0
  253.         )
  254.         else
  255.             self.lastTime := theEvent.timeStamp
  256.     )
  257.     else (
  258.         self._selectedLine := -1 -- force @doAction to occur
  259.         selectLine self selectedLine @doAction
  260.         self.lastTime := theEvent.timeStamp
  261.     )
  262.     
  263.     self.lastLine := selectedLine
  264.     @accept
  265. )
  266.  
  267. method tickle self {class ScrollBox} clock ->
  268. (
  269.     local tempPoint := self.tempPoint
  270.     local screenCoords := ScrollBox.mouse.currentCoords
  271.     SetTo tempPoint screenCoords
  272.     ScreenToDisplay self.window.displaySurface tempPoint @mutate
  273.     SurfaceToLocal self tempPoint @mutate
  274.     local targetP := self.targetPresenter
  275.     
  276.     
  277.     local bbox := self.clippingPresenter.boundary
  278.     local y1 := bbox.y1
  279.     local y2 := bbox.y2
  280.     local mouseY := tempPoint.y
  281.         
  282.     if (mouseY < y1) then (
  283.         if (self._selectedLine > 0) do
  284.             repeatScrollAction self targetP @up
  285.     )
  286.     else if (mouseY > y2) then
  287.     (
  288.         if (self._selectedLine < self.numLines) do
  289.             repeatScrollAction self targetP @down
  290.     )
  291.     else (
  292.         LocalToSurface self tempPoint @mutate
  293.         SurfaceToLocal targetP tempPoint @mutate
  294.         self.selectedLine := \
  295.             ((tempPoint.y / self.stepAmount) as ImmediateInteger) + 1
  296.     )
  297. )
  298.  
  299. method repeatScrollAction self {class ScrollBox} targetPresenter direction ->
  300. (
  301.     local y  := -targetpresenter.y
  302.     local stepAmount := self.stepAmount
  303.     if (direction = @up) then (
  304.         local topPoint := y - stepAmount
  305.         scrollTo self 0 topPoint
  306.         if (topPoint < 0) do topPoint := 0
  307.         self.selectedLine := ((topPoint / stepAmount)  as ImmediateInteger) + 1
  308.     )
  309.     else if (direction = @down) do (
  310.         local bottomPoint := y + stepAmount
  311.         scrollTo self 0 bottomPoint
  312.         bottomPoint := bottomPoint + self.height
  313.         local newLine := ((bottomPoint / stepAmount)  as ImmediateInteger)
  314.         local numLines := self.numLines
  315.         if (newLine > numLines) do
  316.             newLine := numLines
  317.         self.selectedLine := newLine
  318.     )
  319. )
  320.  
  321. method draw self {class ScrollBox} surface clip ->
  322. (
  323.     NextMethod self surface clip
  324.     drawLoweredFrame self.frame surface clip self.globalTransform
  325. )
  326.  
  327. method layout self {class ScrollBox} ->
  328. (
  329.     ThreadCriticalUp() -- prevent visual jumping of vScroll
  330.         NextMethod self
  331.         local ht := self.height
  332.         self.maxScroll := self.targetPresenter.height - ht
  333.         local cp := self.clippingPresenter
  334.         cp.width := cp.width - 4
  335.         cp.height := cp.height - 4
  336.         
  337.         local stepAmount := self.stepAmount
  338.         -- page a line less than a scrollbox worth
  339.         self.pageAmount := (self.height/stepAmount - 1)*stepAmount
  340.         local vScroll := self.vertScrollBar
  341.         if (vScroll <> undefined) do (
  342.             vScroll.pageAmount := self.pageAmount
  343.             vScroll.y := 2
  344.             vScroll.height := ht - 4
  345.             vScroll.x := vScroll.x - 2
  346.             vScroll.stepAmount := stepAmount
  347.         )
  348.     ThreadCriticalDown()
  349.     self
  350. )
  351.  
  352. method selectLine self {class ScrollBox} theLine doAction ->
  353. (
  354.     if (theLine <> self._selectedLine and theLine > 0 and \
  355.         theLine <= self.numLines ) then (
  356.         ThreadCriticalUp()
  357.         if (doAction = @doAction and self.selectAction != undefined) do 
  358.             self.selectAction self.authorData theLine
  359.         selectLine self.selection theLine doAction
  360.         self._selectedLine := theLine
  361.         local lineHt := self.stepAmount
  362.         local startLine := round(-self.targetPresenter.y/lineHt) + 1
  363.         local endLine := \
  364.             (startLine + (self.height - 5 + lineHt)/lineHt - 1) as ImmediateInteger
  365.         if (theLine < startLine or theLine > endLine) do (
  366.             ScrollTo self 0 ((theLine - 1)*lineHt)
  367.         )
  368.         ThreadCriticalDown()
  369.     )
  370. )
  371.  
  372. method afterLoading self {class ScrollBox} stream ->
  373. (
  374.     NextMethod self self stream
  375.     load self.downInterest
  376.     load self.upInterest
  377. )
  378.  
  379. method fontSetter self {class ScrollBox} newFont ->
  380. (
  381.     self.stepAmount := newFont.leading
  382.     if (self.vertScrollBar != undefined) do
  383.         self.vertScrollBar.stepAmount := self.stepAmount
  384.     changeFont self.selection newFont self._selectedLine
  385.     layout self
  386.     newFont
  387. )
  388.  
  389.  
  390. method selectedLineGetter self {class ScrollBox} ->
  391.     self._selectedLine
  392.  
  393. method selectedLineSetter self {class ScrollBox} newLine -> 
  394. (
  395.     selectLine self newLine @doAction
  396.     newLine
  397. )
  398.  
  399. method numLinesGetter self {class ScrollBox} ->
  400. (
  401.     local stepAmount := self.stepAmount
  402.     ((self.targetPresenter.height)/stepAmount) as ImmediateInteger
  403. )
  404.  
  405. method widthSetter self {class ScrollBox} newWidth->
  406. (
  407.     self.selection.width := newWidth
  408.     self.targetPresenter.width := newWidth
  409.     NextMethod self newWidth
  410. )
  411.  
  412. method valueGetter self {class ScrollBox} ->
  413. (
  414.     GetNthKey self._list self._selectedLine
  415. )
  416.  
  417. method valueSetter self {class ScrollBox} newValue ->
  418. (
  419.     local scrollList := self._list
  420.     selectLine self (GetOrdOne scrollList (GetOne scrollList newValue)) @doAction
  421.     self.value
  422. )
  423.     
  424. method listGetter self {class ScrollBox} -> self._list
  425.  
  426. method fillGetter self {class ScrollBox} -> self.clippingPresenter.fill
  427. method fillSetter self {class ScrollBox} newFill ->
  428. (
  429.     self.clippingPresenter.fill := newFill
  430.     NextMethod self undefined
  431. )
  432.  
  433. class ScrollListBox(ScrollBox)
  434. end
  435.  
  436. method init self {class ScrollListBox} #rest args #key \
  437.     boundary:                        \
  438.     list:(#())                        \
  439.     font:(theSystemFont)            \
  440.     ->
  441. (
  442.     local targetPresenter := apply new ListBox \
  443.         width:boundary.width args
  444.     apply NextMethod self boundary:boundary \
  445.         targetPresenter:targetPresenter args
  446.     self.list := list
  447. )
  448.  
  449. method fontGetter self {class ScrollListBox} -> self.targetPresenter.font
  450. method fontSetter self {class ScrollListBox} newFont ->
  451. (
  452.     self.targetPresenter.font := newFont
  453.     NextMethod self newFont
  454. )
  455.  
  456. method listSetter self {class ScrollListBox} newList ->
  457. (
  458.     self._list := self.targetPresenter.list := newList
  459.     selectLine self 1 @dontAction    
  460.     layout self
  461.     newList
  462. )    
  463.  
  464. method numLinesGetter self {class ScrollListBox} -> self.targetPresenter.numLines
  465.  
  466. class MultiListBox(ScrollBox)
  467. instance variables
  468.     numColumns
  469. end
  470.  
  471. --sample list: #(#(1,@a),#(2,@b))
  472. --1 & 2 are in first column, a & b in second.  1&a are across
  473. --from one another as or 2&b
  474. method init self {class MultiListBox} #rest args #key \
  475.     boundary:                        \
  476.     font:(theSystemFont)            \
  477.     list:(#())                        \
  478.     numColumns:                        ->
  479. (
  480.     local targetPresenter := new TwoDMultiPresenter boundary:(copy boundary)
  481.     apply NextMethod self targetPresenter:targetPresenter \
  482.         boundary:boundary args
  483.     if (numColumns = unsupplied) do
  484.         numColumns := size list[1]
  485.     self.numColumns := numColumns
  486.     local columnWidth := self.clippingPresenter.width / numColumns
  487.     for i := 1 to numColumns do (
  488.         local lb := new ListBox width:columnWidth font:font
  489.         lb.x := (columnWidth * (i - 1))
  490.         append targetPresenter lb
  491.     )
  492.     self.list := list
  493. )
  494.  
  495. fn setFont aListBox font ->
  496. (
  497.     if (isAKindOf aListBox ListBox) do
  498.         aListBox.font := font
  499. )
  500.  
  501. method fontGetter self {class MultiListBox} ->
  502. (
  503.     local aListBox := chooseOne self.targetPresenter \
  504.         (a -> isAKindOf a ListBox) undefined
  505.     aListBox.font
  506. )
  507.  
  508. method fontSetter self {class MultiListBox} newFont ->
  509. (
  510.     foreach self.targetPresenter setFont newFont
  511.     NextMethod self newFont
  512. )
  513.  
  514. method listSetter self {class MultiListBox} newList ->
  515. (
  516.     self._list := newList
  517.     selectLine self 1 @dontAction
  518.     local targetP := self.targetPresenter
  519.     for i := 1 to self.numColumns do
  520.         targetP[i+1].list := for j in newList collect j[i]
  521.     targetP.height := targetP[2].height
  522.     layout self
  523.     newList
  524. )
  525.  
  526. method widthSetter self {class MultiListBox} val ->
  527. (
  528.     local origWidth, ratio, targetP, pos
  529.     
  530.     origWidth := self.width
  531.     ratio := val / origWidth
  532.     nextMethod self val
  533.     
  534.     targetP := self.targetPresenter
  535.     pos := 0
  536.     for pres in targetP do (
  537.         if (isAKindOf pres ListBox) do (
  538.             pres.x := pos
  539.             pres.width := ratio * pres.width
  540.             pos := pos + pres.width
  541.             )
  542.         )
  543.     val
  544. )
  545.  
  546. method numLinesGetter self {class MultiListBox} ->
  547. (
  548.     self.targetPresenter[2].numLines
  549. )
  550.